pro haloe_clim_read,file,$
       year,lat,z,nz,month,doy,num_obs,ztrop,ztrop_std,zctop,zctop_std,p,p_std,t,t_std,$
       h2o,h2o_std,o3,o3_std,ch4,ch4_std,hcl,hcl_std,hf,hf_std,no,no_std,no2,no2_std,$
       a245,a245_std,a340,a340_std,a346,a346_std,a526,a526_std

;-----------------------------------------------------------------------------
; Routine reads HALOE aerosol climatology data from a netcdf file.
;
; Input:
;   file.......complete path + name of the HALOE file
;
; Output:
;   year.......year (YYYY)
;   lat........latitude grid, bin centers (degrees), vector
;   z..........altitude grid (km), vector
;   month......month grid (month number), vector
;   doy........day of year (month middle), vector
;   num_obs....# observations in a given latitude - month bin, fltarr(month, latitude)
;
;   ztrop......tropopause altitude, median (km), fltarr(month, latitude)
;   ztrop_std..tropopause altitude, median absolute deviation (km), fltarr(month, latitude)
;   zctop......cloud top altitude, median of non-zero tops (km), fltarr(month, latitude)
;   zctop_std..cloud top altitude, median absolute deviation of non-zero tops (km), fltarr(month, latitude)
;
;  The profile data below are fltarr(time, latitude, altitude)
;
;   p..........pressure mean (mb)
;   p_std......pressure standard deviation (mb)
;   t..........temperature mean (K)
;   t_std......temperature standard deviation (K)
;
;   h2o......water vapor, ppmv
;   h2o_std..water vapor standard deviation, ppmv
;   no2......no2, ppbv
;   no2_std..no2 standard deviation, ppbv
;   o3.......ozone, ppmv
;   o3_std...ozone standard deviation, ppmv
;   no.......nitric oxide, ppbv
;   no_std...nitric oxide standard deviation, ppbv
;   ch4......methane, ppmv
;   ch4_std..methane standard deviation, ppmv
;   hcl......hcl, ppbv
;   hcl_std..hcl standard deviation, ppbv
;   hf.......hf, ppbv
;   hf_std...hf standard deviation, ppbv
;
;   a245.......2.45 micron extinction  (1/km)
;   a245_std...2.45 micron extinction deviation  (1/km)
;   a340.......3.40 micron extinction  (1/km)
;   a340_std...3.40 micron extinction deviation  (1/km)
;   a346.......3.46 micron extinction  (1/km)
;   a346_std...3.46 micron extinction deviation  (1/km)
;   a526.......5.26 micron extinction  (1/km)
;   a526_std...5.26 micron extinction deviation  (1/km)
;    
; Source: Mark Hervig (GATS Inc.)
;
;-----------------------------------------------------------------------------------

;- open the file

   id   = ncdf_open(file)
   glob = ncdf_inquire(id)

;- echo information about the data

   print,'data dimensions: '

   for i=0,glob.ndims-1 do begin
     ncdf_diminq,id,i,name,size
     print,'    ', name, size
   endfor

   print, 'Variable information: '

   for i=0,glob.nvars-1 do begin

     info = ncdf_varinq(id, i)
     print,info.name

     for j=0,info.natts-1 do begin
     
       attname = ncdf_attname(id,i,j)
       ncdf_attget,id,i,attname,attvalue
       print,'    ',attname, ' = ', string(attvalue)
       
     endfor
     
   endfor

;- read the data

   ncdf_varget,id,'bin-center-latitude', lat
   ncdf_varget,id,'altitude', z
   ncdf_varget,id,'month', month
   ncdf_varget,id,'year', year
   ncdf_varget,id,'day-of-year', doy
   
   ncdf_varget,id,'number-of-observations',num_obs
   
   ncdf_varget,id,'tropopause-height',ztrop
   ncdf_varget,id,'tropopause-height-deviation',ztrop_std
   
   ncdf_varget,id,'cloud-top-height',zctop
   ncdf_varget,id,'cloud-top-height-deviation',zctop_std

   ncdf_varget,id,'pressure',    p   
   ncdf_varget,id,'pressure-deviation',    p_std 
   
   ncdf_varget,id,'temperature', t
   ncdf_varget,id,'temperature-deviation', t_std
   
   ncdf_varget,id,'H2O', h2o
   ncdf_varget,id,'H2O-deviation', h2o_std
   
   ncdf_varget,id,'O3', o3
   ncdf_varget,id,'O3-deviation', o3_std
   
   ncdf_varget,id,'CH4', ch4 
   ncdf_varget,id,'CH4-deviation', ch4_std
   
   ncdf_varget,id,'HCl', hcl
   ncdf_varget,id,'HCl-deviation', hcl_std
   
   ncdf_varget,id,'HF', hf 
   ncdf_varget,id,'HF-deviation', hf_std
   
   ncdf_varget,id,'NO',  no
   ncdf_varget,id,'NO-deviation', NO_std
   
   ncdf_varget,id,'NO2', no2 
   ncdf_varget,id,'NO2-deviation', no2_std   
   
   ncdf_varget,id,'2.45-micron-extinction', a245
   ncdf_varget,id,'3.40-micron-extinction', a340
   ncdf_varget,id,'3.46-micron-extinction', a346
   ncdf_varget,id,'5.26-micron-extinction', a526
   
   ncdf_varget,id,'2.45-micron-extinction-deviation', a245_std
   ncdf_varget,id,'3.40-micron-extinction-deviation', a340_std
   ncdf_varget,id,'3.46-micron-extinction-deviation', a346_std
   ncdf_varget,id,'5.26-micron-extinction-deviation', a526_std
   
   nz = n_elements(z)
   
;- close the file

   ncdf_close,id
   
;- done

   return
   end