pro haloe_vpmc_read_summary,file,date,mode,time,lat,lon,t,h2o,zmax,ext_zm,mice_zm,iwc
   
;--------------------------------------------------------------------------------------
; Routine reads the HALOE Vpmc summary files available online at:
;   http://gwest.gats-inc.com/haloe_pmc_project/HALOE_PMC_project.html
;
; Input:
;   file.......complete path + name of the file
;
; Output:
;   date.....date (yyyyddd) 
;   mode.....occultation mode, 0=sunrise, 1=sunset
;   time.....hh.hh (UT)
;   lat......latitude (deg)
;   lon......longitude (deg E)
;   t........80km temperature (K)
;   h2o......80km H2O (ppmv)
;   zmax.....altitude of the PMC extinction peak (km)
;   ext_zm...peak PMC extinction at 3.40 um wavelength (1/km)
;   mice_zm..peak PMC mass density (g/km3)
;   iwc......vertical column mass (g/km2)
;
; Source: Mark Hervig
;--------------------------------------------------------------------------------------

   print,'read_haloe_vpmc_summary.pro is reading...'
   
   head  = ' '
   dat   = fltarr(11)
   nr    = 0 ; # of records
   
   openr,lu,file,/get_lun
   
;- read the file

   for i=1,5 do readf,lu,head      
   
   while (not eof(lu)) do begin
   
     readf,lu,dat
     
     if (nr eq 0) then data = dat
     if (nr gt 0) then data = [[data],[dat]]
   
     nr = nr + 1
     
   endwhile
    
   close,lu
   free_lun,lu
   
;- parse out the data

   date    = long(reform(data(0,*)))
   mode    = reform(data(1,*))
   time    = reform(data(2,*))
   lat     = reform(data(3,*))
   lon     = reform(data(4,*))
   t       = reform(data(5,*))
   h2o     = reform(data(6,*))   
   zmax    = reform(data(7,*))
   ext_zm  = reform(data(8,*))   
   mice_zm = reform(data(9,*))
   iwc     = reform(data(10,*))
   
;- done

   print,'haloe_vpmc_read_summary.pro is returning ',nr,' records

   return
   end