function index_lta_vis,wts,wtn,xl,t

;---------------------------------------------------------------------------
; Purpose:
;   Calculate the refractive index of liquid ternary hno3-h2o-h2so4 aerosols
;   at visible wavelengths (< 2 micron) as described in Luo et al., GRL, 1997.

; Input:
;   t.......temperature in K             
;   wts.....wt fraction of H2SO4
;   wtn.....wt fraction of HNO3        
;   xl......wavelength in um
;
; Output:
;   refra...relative refractive index
;
; Called functions: AH2O, AHNO3, ASUL, RHO1
;
;---------------------------------------------------------------------------


      if (t lt 185. or t gt 370. or  wts+wtn gt 0.7 or $ 
          wts+wtn lt .05 or xl lt .23 or xl gt 2.) then $
          print,'out of range in index_lta_vis.pro'

      wt  = wts+wtn
      rho = rho1(wts,wtn,t)
      a   = (1.e0-wt)*rho /18.016e0 *ah2o(xl)+ wts*rho/98.08e0*asul(wt,xl)+ $
             wtn*rho /63.016e0 *ahno3(wt,xl)

      result = sqrt( (1.e0+2.e0*a)/(1-a)  )

      return,result
      end



;---------------------------------------------------------------------
;     Molar refractivity of HNO3

      function ahno3,wtn,xll

      x = [10.334,5.2775E-2,0.253884,-1.4189,0.100885,0.639675,1.016624,-0.136856,-1.218]

      a     = x(0)+  x(3)*wtn+x(6)*wtn^2
      xm    = x(1)+ x(4)*wtn+x(7)*wtn^2
      xl0   = x(2)+x(5)*wtn+x(8)*wtn^2
      ahno3 = a+xm/(xll^2-xl0^2)

      return,ahno3
      end

;---------------------------------------------------------------------
;     Molar refractivity of H2SO4

      function asul,wts,lambda

      x = [9.134298065,8.853334E-04,-5.537325E-08,1.1290527381E-12, $
           -5.69309238E-19,-6.1259608,2.052362834E-03,-2.651123808E-07, $
           1.33055293E-11,-2.2648372E-16,12.065,-1.303527269E-03, $
           6.90377741E-08,-2.863741935E-12,4.76286166E-17,48.95, $
           -2.35735371E-02,2.8358018E-06,-1.2611534E-10,1.923364E-15]

      xmu  = 1.e4/lambda
      ww   = (wts-0.5e0)
      x1   = x(0)+x(5)*ww+x(10)*ww^2+x(15)*ww^3
      x2   = x(1)+x(6)*ww+x(11)*ww^2+x(16)*ww^3
      x3   = x(2)+x(7)*ww+x(12)*ww^2+x(17)*ww^3
      x4   = x(3)+x(8)*ww+x(13)*ww^2+x(18)*ww^3
      x5   = x(4)+x(9)*ww+x(14)*ww^2+x(19)*ww^3
      asul = x1+x2*xmu+x3*xmu^2+x4*xmu^3+x5*xmu^4

      return,asul
      end


;---------------------------------------------------------------------
;     Molar refractivity of H2O

      function ah2o,lambda

      ah2o = 0.

      b1 = [1.4211, 7.540441E-04, -9.81512155E-08,  5.7218513E-12 , -1.237611E-16]
      b2 = [3.506813, 1.6411E-05, -4.61273E-10,  1.2763141E-14, -3.579466E-20 ]

      x = 1.E4/lambda
     
      ah2o=b2(0)+b2(1)*x+b2(2)*x^2+b2(3)*x^3+b2(4)*x^4

      if (x le 1.23E4) then begin
        ah2o=b1(0)+b1(1)*x+b1(2)*x^2+b1(3)*x^3+b1(4)*x^4
      endif
 
      return,ah2o
      end

;---------------------------------------------------------------------
;     Density of ternary solution in g/cm3

      function rho1,wts,wtn,t

      x = [2.393284E-02,-4.359335E-05,7.961181E-08,0.0,-0.198716351, $
           1.39564574E-03,-2.020633E-06,0.51684706,-3.0539E-03,4.505475E-06, $
           -0.30119511,1.840408E-03,-2.7221253742E-06,-0.11331674116, $
           8.47763E-04,-1.22336185E-06,0.3455282,-2.2111E-03,3.503768245E-06, $
           -0.2315332,1.60074E-03,-2.5827835E-06]

      w   = wts+wtn
      wth = 1.-w
      v1  = x(0)+x(1)*T+x(2)*T^2+x(3)*T^3
      vs  = x(4)+x(5)*T+x(6)*T^2+(x(7)+x(8)*T+x(9)*T^2)*w $
            +(x(10)+x(11)*T+x(12)*T^2)*w*w
      vn  = x(13)+x(14)*T+x(15)*T^2+(x(16)+x(17)*T+x(18)*T^2)*w $
            +(x(19)+x(20)*T+x(21)*T^2)*w*w
      vmcal = wth/18.016*v1 + vs*wts/98.08 + vn*wtn/63.016

      rho1 = 1/vmcal/1000.

      return,rho1
      end