pro intmie,wavl,index,radi,conc, $ ; in
           sext,ssca,sabs,sbac     ; out

;-----------------------------------------------------------------------------
;
; purpose:
;     integrates the mie cross sections over an input particle 
;     size distribution,  to compute total extinction, scattering 
;     and backscattering coefficients.
;
; parameters:
;
; input:  
;     wavl......wavelength (same units as radi)
;     index.....complex refractive index
;     radi......array of aerosol bin center radius (same units as wavl)
;     conc......array of concentration (#/cm3) as a function of radius
;
; output:
;     ssca......total scattering coeff. (1/km)
;     sext......total extinction coeff. (1/km)
;     sabs......total absorption coeff. (1/km)
;     sbac......total backscatter coeff. (1/km 1/sr)
;
; subroutines called:
;     bhmie2   -> calculates the Mie efficiencies 
;
; source: Mark Hervig
;
;-----------------------------------------------------------------------------

      nang = 2          ; for bhmie
      pi   = 3.14159
      nbin = n_elements(radi)

;---- zero the sums

      sext = 0.0
      ssca = 0.0 
      sbac = 0.0 
      sabs = 0.0

;---- loop over radius bins, do Mie calcs

      for j = 0,nbin-1 do begin
        chi   = 2.0 * pi * radi(j) /wavl

        bhmie2,chi,index,nang,s1,s2,ef_ext,ef_sca,ef_bac

        ext  = pi * (radi(j))^2 *conc(j)* ef_ext *1.0e-3 ; 1/km
        sca  = pi * (radi(j))^2 *conc(j)* ef_sca *1.0e-3 ; 1/km
        bac  = (wavl/(2.*pi))^2 *conc(j)* ef_bac *1.0e-3 ; 1/km 1/sr
        sext = sext + ext 
        ssca = ssca + sca
        sbac = sbac + bac
      endfor

      sabs = sext-ssca

      return
      end