pro juldat2,mon,day,yr,julian,cdate,doy

;------------------------------------------------------------------------------
; 
; Purpose:
;   Convert month,day,year into julian date,  and character date
;
; Input:
;   mon    = month (e.g., 10)
;   day    = day (e.g., 7) 
;   yr     = year (e.g., 1993 or 93)
;
; Output:
;   julian = julian date (e.g., 1993280 or 93280,  which is 7-oct-1993)
;   cdate  = date as character string (e.g., '10/7/1993')
;   doy    = day of year
;
; This routine will turn 2 digit years into 4 digit years,  i.e. 99 = 1999
;
; Source: Mark Hervig
;
;------------------------------------------------------------------------------

  dayoff=[0,31,59,90,120,151,181,212,243,273,304,334,365]

  nin = long(n_elements(mon))

  julian = lonarr(nin)
  cdate  = strarr(nin)
  doy    = lonarr(nin)

  for i=0L,nin-1L do begin

    dayoff = [0,31,59,90,120,151,181,212,243,273,304,334,365]

    yyyy = yr(i)

;-  look for 2 digit years

    if (yr(i) le  99 and yr(i) gt 50) then yyyy = 1900+yr(i)
    if (yr(i) le  50) then yyyy = 2000 + yr(i)

    leapyr = yyyy - long(yyyy/4) * 4

    for im = 0,12 do if (leapyr eq 0 and im ge 2) then dayoff(im)=dayoff(im)+1 

    dd        = dayoff(mon(i)-1) + day(i)

    julian(i) = yyyy*1000L + dd

    cd = strtrim(string(fix(mon(i))),2)+'/'+strtrim(string(fix(day(i))),2)+$
                                  '/'+strtrim(string(fix(yyyy)),2)

    cdate(i) = strtrim(string(cd),2)

    doy(i) = dd
    
  endfor
  
  if (nin eq 1) then begin
    julian = julian(0)
    cdate = cdate(0)
    doy = doy(0)
  endif

  return
  end