function molec_scatter2,p,t,wave

;------------------------------------------------------------------------
; Purpose:
;   Calculate molecular (Rayleigh) scattering coefficient
;   using method reported by Bodhaine et al. [1999].
;   The constants (a, b, & c below) are a fit to the results of 
;   Bodhaine et al. [1999] by Eric Shettle (NRL), and are valid 
;   for wavelengths from 200 to 2000 nm.
;
; Input:
;   wave   = wavelength (nm)
;   t      = temperature (K)
;   p      = pressure (mb)
;
; Output:
;   ray    = molecular scattering coefficient (1/km)
;
; References:
;   Bates, D.R., [1984] "Rayleigh Scattering by Air", Planet. Space Sci., 32, 785-790.
;   Bodhaine, B.A., N.B. Wood, E.G. Dutton, & J.R. Slusser, [1999], "On Rayleigh 
;     Optical Depth Calculations", J. Atmos. Ocean. Tech., 16, 1854-1861.
;   Peck, E.R. and K. Reeder, [1972], "Dispersion of Air", J. Opt. Soc. Am., 62, 958-962.
;
; Source: Mark Hervig, GATS Inc.
;------------------------------------------------------------------------
   
;- calculate atmospheric (molecular) density

   Avgdro = 6.02e23      ; Avagadro's #,  molecules per mole
   Md     = 0.028964     ; Molecular weight dry air (Kg/mol)
   R      = 287.05       ; gas constatnt,  J/kg/K
   
   dens = 1.e-6 *(p*100.0/(R*T))*Avgdro/Md  ; molecular density (molecules/cm3)
   
;- the scattering coefficient calculation

   a = 3.96815d-16
   b = -1.15682d4
   c = -3.68073d7
   
   xsec = a * wave^(-4.0) / (1.0 + b*wave^(-2.0) + c*wave^(-4.0))  ; cross section (cm^2/molecule)
   
   ray  = xsec * dens * 1e5  ; scattering (1/km)
   
;- done

   return,ray   
   end