function sulfate_tabaz,p,t,h2o

;----------------------------------------------------------------------------
; Purpose:
;    This routine calculates the equilibrium composition of h2so4 aerosols
;    as a function of temperature,  pressure,  and H2O mixing ratio, using
;    the parameterization of Tabazadeh et al., GRL, p1931, 1997.
;
; Parameters:
;
;   input:
;      t.....temperature (K)
;      h2o...water vapor mixing ratio (ppmv)
;      p.....pressure (mb)
;
;   output:
;      result......the sulfuric acid composition (wt % h2so4)
;
; Source:  Mark Hervig 
;----------------------------------------------------------------------------
;
;- partial pressure of ambient h2o

   pph2o = h2o * 1.e-6 * p

;- saturation water vapor partial pressure,  mb

   pph2osat = 18.452406985 - 3505.1578807/t - 330918.55082/(t^2)  + 12725068.262/(t^3)

   pph2osat = exp(pph2osat)

;- water activity

   aw = pph2o/pph2osat

;- composition

   if (aw gt 0.0  and aw le 0.05) then begin
     y1 = 12.372089320*aw^(-0.16125516114) -30.490657554*aw -2.1133114241
     y2 = 13.455394705*aw^(-0.19213122550) -34.285174607*aw -1.7620073078
   endif
  
   if (aw gt 0.05 and aw le 0.85) then begin
     y1 = 11.820654354*aw^(-0.20786404244) -4.8073063730*aw -5.1727540348
     y2 = 12.891938068*aw^(-0.23233847708) -6.4261237757*aw -4.9005471319
   endif

   if (aw gt 0.85) then begin
     y1 = -180.06541028*aw^(-0.38601102592) -93.317846778*aw +273.88132245
     y2 = -176.95814097*aw^(-0.36257048154) -90.469744201*aw +267.45509988
   endif

   sulfmolal = y1+((t-190.)*(y2-y1)/70.)

   wts = 9800.*sulfmolal/(98.*sulfmolal+1000.)  ; % h2so4

   return,wts
   end